VBA UserForm: Tạo Giao Diện Nhập Liệu Chuyên Nghiệp Trong Excel

Private Sub btnLuu_Click()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Data")
    
    ' Tìm dòng trống cuối cùng
    Dim lastRow As Long
    lastRow = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row + 1
    
    ' Ghi dữ liệu từ form vào sheet
    ws.Cells(lastRow, 1).Value = txtHoTen.Value
    ws.Cells(lastRow, 2).Value = txtEmail.Value
    ws.Cells(lastRow, 3).Value = cboPhongBan.Value
    ws.Cells(lastRow, 4).Value = Now()
    
    ' Thông báo thành công
    MsgBox "Đã lưu thành công!", vbInformation
    
    ' Xoá form để nhập tiếp
    Call ClearForm
End Sub

Private Sub UserForm_Initialize()
    ' Đổ dữ liệu vào ComboBox
    With cboPhongBan
        .AddItem "Kế toán"
        .AddItem "Nhân sự"
        .AddItem "Kinh doanh"
        .AddItem "IT"
        .AddItem "Sản xuất"
    End With
    
    ' Set giá trị mặc định
    txtHoTen.SetFocus
End Sub

Private Function ValidateForm() As Boolean
    ValidateForm = True
    
    ' Kiểm tra họ tên không được trống
    If Trim(txtHoTen.Value) = "" Then
        MsgBox "Vui lòng nhập họ tên!", vbExclamation
        txtHoTen.SetFocus
        ValidateForm = False
        Exit Function
    End If
    
    ' Kiểm tra email có @ 
    If InStr(txtEmail.Value, "@") = 0 Then
        MsgBox "Email không hợp lệ!", vbExclamation
        txtEmail.SetFocus
        ValidateForm = False
        Exit Function
    End If
    
    ' Kiểm tra phòng ban đã chọn chưa
    If cboPhongBan.ListIndex = -1 Then
        MsgBox "Vui lòng chọn phòng ban!", vbExclamation
        cboPhongBan.SetFocus
        ValidateForm = False
        Exit Function
    End If
End Function

Sub MoFormNhapLieu()
    frmNhapLieu.Show
End Sub